vers l'index général de l'aide
vers l'index des media

media - scattering (dispersion)

Le "scattering" est la manière dont la lumière se diffuse dans les atmosphères un peu plus dense que la normale : brouillard, poussière, fumée,...

Cet effet est dû au fait que les particules (eau, pollens,..) présentes dans l'air "accrochent" la lumière, et laissent une trace visible.

syntaxe

media {
...
scattering {Type, 
            Couleur
           [eccentricity Excentricite]
           [extinction Extinction]
           }
}

Le type définit la manière dont la lumière se diffuse dans l'atmosphère. Dans la réalité, un filet de lumière vu de face ou presque est plus intense que s'il est vu de côté. C'est cela qui est déterminé par les 5 types de scattering disponibles.

Type 1 : dispersion isotrope, où l'angle sous lequel est vue la dispersion lumineuse n'a pas d'incidence sur son intensité. C'est le type que l'on choisira pour les premiers tests lors de la définition d'un tel media.

Types 2, 3, 4 et 5 : modèles de dispersion où l'intensité de l'effet varie suivant l'angle de vision. Ces modèles sont détaillés dans la page suivante.

exemple

//dispositif général
#include "colors.inc"
camera {location <250,150,250> direction z*1 look_at <0,120,0>}
plane {y,0 pigment {SteelBlue}}

//une petite sphère qui se met dans le trajet de la lumière
sphere {<0,160,0>,30 pigment {OrangeRed} finish {phong .7}}

//le conteneur du media
sphere {<0,120,0>,120 hollow pigment {White transmit 1}
 interior {
   media {  
          intervals 10
          samples 1,4
          scattering {
                      1,
                      White*.005
            } 
}         
}
}

light_source {<0,300,-250> White*1}

Voilà : un petit media qui accroche la lumière, et on voit bien la 'trace d'ombre' de la sphère dans la 'poussière'. Dans le principe, ce n'est jamais beaucoup plus compliqué que cela, mais on se retrouve assez facilement à s'arracher les cheveux pour arriver à faire 'fonctionner' un media comme on le souhaite. Le problème, c'est que chaque scène est un cas particulier, et nous ne pouvons que formuler quelques conseils pour vous aider :

- Gardez toujours à l'esprit que l'échantillonnage du media dépend de la taille absolue du conteneur. Donc, veillez à ce que le conteneur soit arrivé à sa taille définitive avant de lui appliquer un media, sinon l'allure de celui-ci sera différente. - Relisez bien la page précédente, qui parle des options d'échantillonnage, qui s'appliquent pareillement à la dispersion. Si votre version de POV-Ray vous le permet, tirez parti du mode d'échantillonnage, afin de contrôler l'aspect final du media. - Essayer d'incorporer rapidement le media à la scène, et d'élaborer l'éclairage de manière adéquate. Mettez d'abord votre media au point avec une seule source, la principale, puis ajoutez les autres lumières une à une, en observant leur influence sur l'aspect du media. - Ne modifiez qu'un seul paramètre à la fois ! Assurez-vous tout d'abord que le paramètre de couleur soit bon, et, comme dans l'exemple ci-dessus, utilisez un multiplicateur pour contrôler son intensité. - N'oubliez pas "hollow" !!

auteur : Fabien Mosen