vers l'index général
vers la page générale des sources lumineuses
Ces pages sont destinées à vous donner quelques bases concernant le choix et le placement des lumières dans une scène. Nous allons commencer par les cas simples, où il s'agit simplement de montrer un objet.
Voilà, vous venez de finir la modélisation de votre presse-agrume préféré, et vous voulez le montrer à tout le monde. Pour cela, il faut le mettre en valeur par un éclairage simple mais efficace.
Puisqu'il s'agit d'un éclairage "utile", et pas artistique, il faut essayer d'éviter les contre-jours et autres effets particuliers. Il ne faut pas non plus placer la source lumineuse au même point que la caméra, ça vous cacherait les ombres, et ce sont justement les ombres qui donnent du relief à un objet.
La bonne position, c'est souvent un point un peu plus haut que la caméra, à la même distance par rapport aux objets, voire même un peu en retrait. La caméra de notre exemple est comme ceci, placée vers -Z, regardant un peu plus haut que l'origine :
camera {location <0, 7, -9> look_at <0, 2, 0>}
Nous pouvons essayer une lumière plus haute, plus à gauche, et plus en arrière par rapport à la caméra :
light_source {<-20, 30, -15> White*1}
En jouant sur la position de la lumière, nous pouvons contrôler l'allure des ombres. Par exemple, en abaissant la lumière, nous aurons des ombres plus "longues" :
light_source {<-20, 15, -15> White*1}
Mais c'est très "grisaillant", tout ça. Pour réveiller le blanc, pas besoin d'un ou deux barils, juste ça :
light_source {<-20, 30, -15> White*2}
Le fond a tendance à s'assombrir, et l'objet flotte un peu, par manque d'environnement. La solution, c'est de circonscrire l'objet à l'aide d'une source conique :
light_source {<-20, 30, -15> White*2
spotlight point_at <0,0,0> radius 7 falloff 10
}
Cela permet aux objets de mieux se détacher, et de s'affirmer comme sujet premier de la scène.
L'augmentation de la luminosité a eu un effet indésirable : le contraste est devenu un peu "dur", et les ombres manquent de subtilité. Pour y remédier, il faut recourir à une deuxième source lumineuse, plus faible, et placée de telle sorte qu'elle éclaire les zones d'ombres, sans toutefois en provoquer (sinon, ça va être la panade).
light_source {<-20, 30, -15> White*1.5 spotlight point_at <0,0,0> radius 7 falloff 10
}
light_source {<10,5,-20> White*.5 shadowless}
Pour donner une tension particulière à l'éclairage, il peut être intéressant de colorer légèrement cette deuxième lumière.
light_source {<10,5,-20> rgb <.5,.5,1>*.7 shadowless}
Enfin, selon la nature de l'objet et la puissance de calcul disponible, profitez-en pour adoucir les ombres en utilisant une area_light :
light_source {<-20, 30, -15> White*1.5 spotlight point_at <0,0,0> radius 7 falloff 10
area_light x*8,z*8,4,4 jitter adaptive 1
}
N'oubliez pas non plus de soigner le choix des textures, même s'il n'est pas définitif. Il est très désagréable d'être agressé par des aplats de vert, rouge et bleu, essayez de trouver des couleurs franches mais nuancées pour mettre votre modèle en valeur, même pendant les étapes de modélisation.
auteur : Fabien Mosen