vers l'index général / vers l'index des caméras et lumières / page précédente : les ombres douces

groupes de lumières

objectif

Éclairer des objets de manière ciblée, sans éclairer toute la scène. Très utile lorsqu'on a une scène dont l'ambiance globale est réussie, mais que l'on veut tricher un peu sur l'éclairage d'un objet en particulier.

syntaxe

light_group {
  light_source {...}

  Objet1
  Objet2
  ...

  (global_lights on/off) //booléen
}

Le groupe se compose donc d'une source lumineuse (ou plusieurs, éventuellement), et d'un ou plusieurs objets. Ces objets seront éclairés exclusivement par cette source, et cette source n'illuminera que ces objets-là.

Si le mot clé global_lights est activé, les objets seront éclairés aussi par les autres sources de la scène, mais la lumière du groupe se contentera toujours d'éclairer uniquement les objets du groupe.

exemple

#include "colors.inc"

camera {location <20,30,70> look_at <0,10,0> angle 30}

light_source {<50,50,0> Blue}

sphere {<0,5,0>,5 pigment {White}}   

light_group {                      
 sphere {<12,5,0>,5 pigment {White}}                         
 light_source {<50,50,50> OrangeRed}
 }

light_group {                      
 sphere {<-12,5,0>,5 pigment {White}}                         
 light_source {<50,50,50> YellowGreen}
 global_lights
 }

plane {y,0 pigment {White}}

Il y a une lumière générale bleue. La sphère du milieu n'appartient pas à un groupe, elle est donc bleue. La sphère de gauche est rouge et seulement rouge parce qu'elle appartient à un groupe qui contient une lumière rouge. Enfin, la sphère de droite reçoit la lumière verte de la source de son groupe, mais également du bleu de la lumière générale (à cause de global_lights), elle vire donc un peu au cyan.

auteur : Fabien Mosen